マクロの使い方です。
　1. Alt＋F11 で、VBEの画面を出します。
　2. 左側のプロジェクト-VBAProjectで、該当するファイルを選択します。
　　 VBAProjectが出ていなければ、Ctrl＋R で出します。
　3. [挿入]、[標準モジュール]、出てきた白い所に、コードを貼付けます。
　4. 右上の × でExcelの画面に戻ります。
　5. 線を引くセルの範囲を選択します。
　6. Alt＋F8 で、「オートシェイプで各種線描画」を選んで、実行します。

また、線の色番号の例は、このマクロでは一部しか表示していませんが、それ以外の色も指定できます。
「オートシェイプの色番号確認」のマクロを実行して頂くと、シートのＡ列に色のサンプルと
Ｂ列に色番号を表示しますので、そちらでご確認ください。

Sub オートシェイプで各種線描画() '線を引く範囲を選択してから実行してください。
　Dim Sentaku As String
　Dim Basho As String
　Dim Tensen As String
　Dim Futosa As String
　Dim Iro As String
　If TypeName(Selection) <> "Range" Then Exit Sub
　If Selection.Areas.Count > 1 Then
　　MsgBox "複数の範囲を選択していると実行できません", vbCritical
　　Exit Sub
　End If
　Do
　　Sentaku = InputBox(Prompt:="どの部分に線を引きますか？" & vbCrLf & vbCrLf & _
　　　　　　　　　　　"1）　選択範囲の全てのセル" & vbCrLf & _
　　　　　　　　　　　"2）　選択範囲の任意の場所のセル", Title:="場所選択", Default:=1)
　　Select Case Sentaku
　　Case ""
　　　Exit Sub
　　Case "1", "2"
　　　Exit Do
　　　End Select
　Loop
　If Sentaku = "2" Then
　　Do
　　　Basho = InputBox(Prompt:="1）外周　2）上　　3）下　　4）左　　5）右", _
　　　Title:="場所選択", Default:=1)
　　　Select Case Basho
　　　Case ""
　　　　Exit Sub
　　　Case "1", "2", "3", "4", "5"
　　　　Exit Do
　　　End Select
　　Loop
　End If
　Do
　Tensen = InputBox(Prompt:="どの線にしますか？" & vbCrLf & _
　　"0）　実線" & vbCrLf & _
　　"1）　点線(丸)" & vbCrLf & _
　　"2）　点線(角)" & vbCrLf & _
　　"3）　破線" & vbCrLf & _
　　"4）　一点鎖線" & vbCrLf & _
　　"5）　長破線" & vbCrLf & _
　　"6）　長鎖線" & vbCrLf & _
　　"7）　長二重鎖線", _
　　Title:="線種選択", Default:=0)
　　Select Case Tensen
　　　Case ""
　　　　Exit Sub
　　　Case "0", "1", "2", "3", "4", "5", "6", "7"
　　　　Exit Do
　　End Select
　Loop
　Do
　　Futosa = InputBox(Prompt:="太さ(たぶん無制限？)を指定してください", _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　Title:="太さ選択", Default:=0.2)
　　If Len(Futosa) = 0 Then Exit Sub
　　If IsNumeric(Futosa) Then
　　If Futosa > 0 Then Exit Do
　　End If
　　Loop
　Do
　　Iro = InputBox(Prompt:="どの色にしますか？" & vbCrLf & _
　　　　　　　　　　　　　　"1）白　　　2）赤　　　3）黄緑　　4）青" & vbCrLf & _
　　　　　　　　　　　　　　"5）黄　　　6）ピンク　7）水色　　8）黒", _
　　　　　　　　　　　　　　　                       Title:="線色選択", Default:=8)
　  If Iro = "" Then Exit Sub
    If Iro > 0 And Iro < 81 Then Exit Do
　Loop
　On Error GoTo TRAP
　Application.ScreenUpdating = False
　Select Case Sentaku
　Case "1"
　　選択した範囲のセル全てに各種線 CInt(Tensen), CSng(Futosa), CInt(Iro)
　Case "2"
　　選択した範囲の任意の部分に各種線 CInt(Tensen), CInt(Basho), CSng(Futosa), CInt(Iro)
　　End Select
　TRAP:
　Application.ScreenUpdating = True
End Sub
Private Sub 選択した範囲のセル全てに各種線(ByVal Tensen As Integer, _
　　　　　　　　　　　　　　　　　　　　　　　　　　　ByVal Futosa As Single, ByVal Iro As Integer)
　Dim Hajime As Long
　Dim Migihashi As Double
　Dim Hidarihashi As Double, Takasa As Double
　Dim Shita As Double, Yoko As Double
　Dim i As Long, ii As Long, j As Long, jj As Long
　Dim k As Long, kk As Long
　On Error GoTo TRAP
　i = Selection.Row '開始行
　j = Selection.Column '開始列
　ii = i + Selection.Rows.Count '終了行
　jj = j + Selection.Columns.Count '終了列
　Hajime = i
　Migihashi = Cells(ii, jj).Left
　Shita = Cells(ii, jj).Top
　'選択範囲に、それぞれ横線を引く
　For k = i To ii
　　If i > ii Then Exit Sub
　　Hidarihashi = Cells(i, j).Left
　　Takasa = Cells(i, j).Top
　　各種線描画_Main Hidarihashi, Takasa, Migihashi, Takasa, Tensen, Futosa, Iro
　　i = i + 1
　Next
　i = Hajime '開始行を戻す
　'選択範囲に、それぞれ縦線を引く
　For kk = j To jj
　　If j > jj Then Exit Sub
　　Yoko = Cells(i, j).Left
　　Takasa = Cells(i, j).Top
　　各種線描画_Main Yoko, Takasa, Yoko, Shita, Tensen, Futosa, Iro
　　j = j + 1
　Next
　TRAP:
End Sub
Private Sub 選択した範囲の任意の部分に各種線(ByVal Tensen As Integer, _
　　　　ByVal Basho As Integer, ByVal Futosa As Single, ByVal Iro As Integer)
　Dim Yokohaba As Single, Tatehaba As Single, Hidarihashi As Double
　Dim Yoko As Double, Takasa As Double
　Dim Shita As Double, Migi As Double, Migihashi As Double
　On Error GoTo TRAP
　Yokohaba = Selection.Width
　Tatehaba = Selection.Height
　Yoko = Selection.Left
　Takasa = Selection.Top
　Migihashi = Yoko + Yokohaba + Futosa / 2
　Hidarihashi = Yoko - Futosa / 2
　Shita = Takasa + Tatehaba
　Migi = Yoko + Yokohaba
　Select Case Basho
　　Case 1 '外周
　　　各種線描画_Main Hidarihashi, Takasa, Migihashi, Takasa, Tensen, Futosa, Iro
　　　各種線描画_Main Hidarihashi, Shita, Migihashi, Shita, Tensen, Futosa, Iro
　　　各種線描画_Main Yoko, Takasa, Yoko, Shita, Tensen, Futosa, Iro
　　　各種線描画_Main Migi, Takasa, Migi, Shita, Tensen, Futosa, Iro
　　Case 2 '上
　　　各種線描画_Main Hidarihashi, Takasa, Migihashi, Takasa, Tensen, Futosa, Iro
　　Case 3 '下
　　　各種線描画_Main Hidarihashi, Shita, Migihashi, Shita, Tensen, Futosa, Iro
　　Case 4 '左
　　　各種線描画_Main Yoko, Takasa, Yoko, Shita, Tensen, Futosa, Iro
　　Case 5 '右
　　　各種線描画_Main Migi, Takasa, Migi, Shita, Tensen, Futosa, Iro
　End Select
TRAP:
End Sub
Private Sub 各種線描画_Main(ByVal BeginX As Double, ByVal BeginY As Double, _
　ByVal EndX As Double, ByVal EndY As Double, _
　ByVal Tensen As Integer, ByVal Futosa As Single, _
　ByVal Iro As Integer)
　ActiveSheet.Shapes.AddLine(BeginX, BeginY, EndX, EndY).Select
　With Selection
　　.ShapeRange.Line.ForeColor.SchemeColor = Iro
　　If Tensen = 0 Then
　　　.ShapeRange.Line.DashStyle = msoLineSolid '線の種類(実線)の設定
　　ElseIf Tensen = 1 Then
　　　.ShapeRange.Line.DashStyle = msoLineRoundDot '線の種類(点線(丸))の設定
　　Else
　　　.ShapeRange.Line.DashStyle = Tensen 'その他の点線の種類の設定
　　End If
　　.ShapeRange.Line.Weight = Futosa '太さの設定
　　.Placement = xlMoveAndSize 'セルにあわせて移動やサイズ変更をする
　End With
End Sub

Sub オートシェイプの色番号確認()
　For i = 1 To 80
　　Cells(i, 2) = i
　　hidarihashi = Cells(i, 1).Left
　　takasa = Cells(i, 1).Top
　　migihashi = Cells(i, 2).Left
　　takasa = Cells(i, 2).Top + Cells(i, 2).Height / 2
　　ActiveSheet.Shapes.AddLine(hidarihashi, takasa, migihashi, takasa).Select
　　Selection.ShapeRange.Line.ForeColor.SchemeColor = i
　　Selection.ShapeRange.Line.Weight = 3
　Next i
End Sub

　　このコードの使い方は、マクロの使い方(１)標準モジュールにあります。

選択範囲内の、既存の罫線（上下左右斜め線）を一括してオートシェイプ（図形）の線に変換します。
線種・太さ・色をできるだけ元の罫線に近いものにしてあり、変換後は、罫線は削除されます。

Private Type tLineFormat
　BeginX As Double
　BeginY As Double
　EndX As Double
　EndY As Double
　Style As Long
　Dash As Long
　Weight As Single
　Color As Long
End Type

Sub Border2ShapeEx()
　Dim TargetArea As Range
　Dim R As Range
　Dim rn As Long
　Dim cn As Long
　Dim LineFormat As tLineFormat
　Dim LineID As Integer
　
　If TypeName(Selection) <> "Range" Then Exit Sub
　If Selection.Areas.Count > 1 Then
　　MsgBox "複数の範囲を選択していると実行できません", vbCritical
　　Exit Sub
　End If
　Set TargetArea = Intersect(Selection, ActiveSheet.UsedRange)
　If TargetArea Is Nothing Then Exit Sub
　With TargetArea
　
　　'上横線変換
　　For rn = 1 To .Rows.Count
　　　ChangeLineH TargetArea, xlEdgeTop, LineFormat, rn
　　Next
　　
　　'下端横線変換
　　ChangeLineH TargetArea, xlEdgeBottom, LineFormat, .Rows.Count
　　
　　'左縦線変換
　　For cn = 1 To .Columns.Count
　　　ChangeLineV TargetArea, xlEdgeLeft, LineFormat, cn
　　Next
　　
　　'右端縦線変換
　　ChangeLineV TargetArea, xlEdgeRight, LineFormat, .Columns.Count
　　
　　'斜線変換
　　For Each R In TargetArea
　　　With R
　　
　　　　'右上がり
　　　　LineID = GetLineIndex(R, xlDiagonalUp, LineFormat)
　　　　If LineID > 1 Then
　　　　　LineFormat.BeginX = .Left
　　　　　LineFormat.BeginY = .Top + .Height
　　　　　LineFormat.EndX = .Left + .Width
　　　　　LineFormat.EndY = .Top
　　　　　DrawLine LineFormat
　　　　End If
　　　
　　　　'右下がり
　　　　LineID = GetLineIndex(R, xlDiagonalDown, LineFormat)
　　　　If LineID > 1 Then
　　　　　LineFormat.BeginX = .Left
　　　　　LineFormat.BeginY = .Top
　　　　　LineFormat.EndX = .Left + .Width
　　　　　LineFormat.EndY = .Top + .Height
　　　　　DrawLine LineFormat
　　　　End If
　　　End With
　　Next
　
　　'罫線削除
　　.Borders(xlDiagonalUp).LineStyle = xlLineStyleNone
　　.Borders(xlDiagonalDown).LineStyle = xlLineStyleNone
　　.Borders(xlEdgeLeft).LineStyle = xlLineStyleNone
　　.Borders(xlEdgeTop).LineStyle = xlLineStyleNone
　　.Borders(xlEdgeBottom).LineStyle = xlLineStyleNone
　　.Borders(xlEdgeRight).LineStyle = xlLineStyleNone
　　.Borders(xlInsideVertical).LineStyle = xlLineStyleNone
　　.Borders(xlInsideHorizontal).LineStyle = xlLineStyleNone
　　.Select
　End With
　Set R = Nothing
　Set TargetArea = Nothing
End Sub

Private Function GetLineIndex(ByRef Target As Range, _
　ByVal BorderID As Long, _
　ByRef LineFormat As tLineFormat) As Integer
　With Target.Borders(BorderID)
　　LineFormat.Color = .Color
　　If .LineStyle = xlLineStyleNone Then
　　　GetLineIndex = 1
　　　LineFormat.Style = 0
　　　LineFormat.Dash = 0
　　　LineFormat.Weight = 0
　　　LineFormat.Color = -1
　　ElseIf .LineStyle = xlContinuous And _
　　　.Weight = xlHairline Then
　　　GetLineIndex = 2
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineSolid
　　　LineFormat.Weight = 0.25
　　ElseIf .LineStyle = xlDot Then
　　　GetLineIndex = 3
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineRoundDot
　　　LineFormat.Weight = 0.5
　　ElseIf .LineStyle = xlDashDotDot And _
　　　.Weight = xlThin Then
　　　GetLineIndex = 4
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineDashDotDot
　　　LineFormat.Weight = 0.5
　　ElseIf .LineStyle = xlDashDot And _
　　　.Weight = xlThin Then
　　　GetLineIndex = 5
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineLongDashDot
　　　LineFormat.Weight = 0.5
　　ElseIf .LineStyle = xlDash And _
　　　.Weight = xlThin Then
　　　GetLineIndex = 6
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineSquareDot
　　　LineFormat.Weight = 0.5
　　ElseIf .LineStyle = xlContinuous And _
　　　.Weight = xlThin Then
　　　GetLineIndex = 7
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineSolid
　　　LineFormat.Weight = 0.75
　　ElseIf .LineStyle = xlDashDotDot And _
　　　.Weight = xlMedium Then
　　　GetLineIndex = 8
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineDashDotDot
　　　LineFormat.Weight = 1.25
　　ElseIf .LineStyle = xlSlantDashDot Then
　　　GetLineIndex = 9
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineLongDashDot
　　　LineFormat.Weight = 1.5
　　ElseIf .LineStyle = xlDashDot And _
　　　.Weight = xlMedium Then
　　　GetLineIndex = 10
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineLongDashDot
　　　LineFormat.Weight = 1.25
　　ElseIf .LineStyle = xlDash And _
　　　.Weight = xlMedium Then
　　　GetLineIndex = 11
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineDash
　　　LineFormat.Weight = 1.25
　　ElseIf .LineStyle = xlContinuous And _
　　　.Weight = xlMedium Then
　　　GetLineIndex = 12
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineSolid
　　　LineFormat.Weight = 1.25
　　ElseIf .LineStyle = xlContinuous And _
　　　.Weight = xlThick Then
　　　GetLineIndex = 13
　　　LineFormat.Style = msoLineSingle
　　　LineFormat.Dash = msoLineSolid
　　　LineFormat.Weight = 2
　　ElseIf .LineStyle = xlDouble Then
　　　GetLineIndex = 14
　　　LineFormat.Style = msoLineThinThin
　　　LineFormat.Dash = msoLineSolid
　　　LineFormat.Weight = 3
　　Else
　　　GetLineIndex = 0
　　　LineFormat.Style = 0
　　　LineFormat.Dash = 0
　　　LineFormat.Weight = 0
　　　LineFormat.Color = -1
　　End If
　End With
End Function
　
Private Sub DrawLine(ByRef LineFormat As tLineFormat)
　With ActiveSheet.Shapes.AddLine(LineFormat.BeginX, LineFormat.BeginY, _
　　LineFormat.EndX, LineFormat.EndY).Line
　　.Style = LineFormat.Style
　　.DashStyle = LineFormat.Dash
　　.Weight = LineFormat.Weight
　　.ForeColor.RGB = LineFormat.Color
　End With
End Sub

Private Sub ChangeLineH(ByRef TargetArea As Range, ByVal BorderID As Long, _
　ByRef LineFormat As tLineFormat, ByVal rn As Long)
　Dim NextFormat As tLineFormat
　Dim LineID As Integer
　Dim NextID As Integer
　Dim StartPos As Long
　Dim cn As Long
　Dim R As Range

　With TargetArea
　　For StartPos = 1 To .Columns.Count
　　　Set R = .Cells(rn, StartPos)
　　　LineID = GetLineIndex(R, BorderID, LineFormat)
　　　If LineID > 1 Then
　　　　With LineFormat
　　　　　.BeginX = R.Left
　　　　　.BeginY = R.Top
　　　　　If BorderID = xlEdgeBottom Then .BeginY = .BeginY + R.Height
　　　　　.EndY = .BeginY
　　　　End With
　　　　Exit For
　　　End If
　　Next
　　For cn = StartPos To .Columns.Count
　　　Set R = .Cells(rn, cn)
　　　LineID = GetLineIndex(R, BorderID, LineFormat)
　　　If cn = .Columns.Count Then
　　　　NextID = 99
　　　　NextFormat.Color = -1
　　　Else
　　　　NextID = GetLineIndex(R.Offset(0, 1), BorderID, NextFormat)
　　　End If
　　　With LineFormat
　　　　If LineID <> NextID Or .Color <> NextFormat.Color Then
　　　　　.EndX = R.Left + R.Width
　　　　　If LineID > 1 Then DrawLine LineFormat
　　　　　.BeginX = .EndX
　　　　End If
　　　End With
　　Next
　End With
End Sub

Private Sub ChangeLineV(ByRef TargetArea As Range, ByVal BorderID As Long, _
　ByRef LineFormat As tLineFormat, ByVal cn As Long)
　Dim NextFormat As tLineFormat
　Dim LineID As Integer
　Dim NextID As Integer
　Dim StartPos As Long
　Dim rn As Long
　Dim R As Range
　
　With TargetArea
　　For StartPos = 1 To .Rows.Count
　　　Set R = .Cells(StartPos, cn)
　　　LineID = GetLineIndex(R, BorderID, LineFormat)
　　　If LineID > 1 Then
　　　　With LineFormat
　　　　　.BeginX = R.Left
　　　　　.BeginY = R.Top
　　　　　If BorderID = xlEdgeRight Then .BeginX = .BeginX + R.Width
　　　　　.EndX = .BeginX
　　　　End With
　　　　Exit For
　　　End If
　　Next
　　For rn = StartPos To .Rows.Count
　　　Set R = .Cells(rn, cn)
　　　LineID = GetLineIndex(R, BorderID, LineFormat)
　　　If rn = .Rows.Count Then
　　　　NextID = 99
　　　　NextFormat.Color = -1
　　　Else
　　　　NextID = GetLineIndex(R.Offset(1, 0), BorderID, NextFormat)
　　　End If
　　　With LineFormat
　　　　If LineID <> NextID Or .Color <> NextFormat.Color Then
　　　　　.EndY = R.Top + R.Height
　　　　If LineID > 1 Then DrawLine LineFormat
　　　　.BeginY = .EndY
　　　　End If
　　　End With
　　Next
　End With
End Sub

　　　このコードの使い方は、マクロの使い方(１)標準モジュールにあります。

Index

定数

色 　

　1

　3

　4

　6

　5

　7

　8

　2

LineStyle
プロパティの
定　　数

Weight
プロパティの
定　　数

Border
プロパティの
定　　数

1.　２行目の行番号をクリックして、行全体を選択します。
2.　メニューの【書式】【条件付書式】で、【数式が】を選択して、=MIN($B2:$F2)<=40　と入力し、
　　【書式】のボタンをクリックして、塗りつぶすパターンを選択し、ＯＫします。
3.　【書式のコピー貼り付け】（既定値でメニューの書式の下にある、
　　ハケのマークのアイコン）をクリックし、他の行番号をクリックして、書式をコピーします。

Sub 色見本()
　Dim i As Integer, j As Integer, k As Integer
　Dim L As Double, LL As Double, T As Double, H As Double, W As Double
　On Error Resume Next
　Range("A1:D1").Merge '１行目の見出し欄を結合
　Range("F1:I1").Merge
　With Cells.Font 'フォント設定
　　.Name = "ＭＳ Ｐゴシック"
　　.Size = 12
　　.Strikethrough = False
　　.Superscript = False
　　.Subscript = False
　　.OutlineFont = False
　　.Shadow = False
　　.Underline = xlUnderlineStyleNone
　　.ColorIndex = xlAutomatic
　End With
　Rows("1").RowHeight = 22.5 '行間隔・列間隔設定
　Rows("2").RowHeight = 33
　Rows("3:34").RowHeight = 11.25
　Range("F1:I1,A:A,C:C,F:F,H:H").ColumnWidth = 7
　Range("B:B,D:D,G:G,I:I").ColumnWidth = 10
　Range("A1") = "文字色・罫線色・セル塗りつぶし色見本"
　Range("F1") = "図形線色・図形塗りつぶし色見本"
　Range("A2") = "INDEX" & Chr(10) & "NO"
　Range("B2") = "色見本"
　Range("C2") = "INDEX" & Chr(10) & "NO"
　Range("D2") = "色見本"
　Range("F2") = "INDEX" & Chr(10) & "NO"
　Range("G2") = "色見本"
　Range("H2") = "INDEX" & Chr(10) & "NO"
　Range("I2") = "色見本"
　With Cells
　　.HorizontalAlignment = xlCenter
　　.VerticalAlignment = xlCenter
　End With
　Range("A1:D34,F1:I34").Select
　With Selection.Borders(xlEdgeLeft)
　　.LineStyle = xlContinuous
　　.Weight = xlThick
　　.ColorIndex = 5
　End With
　With Selection.Borders(xlEdgeTop)
　　.LineStyle = xlContinuous
　　.Weight = xlThick
　　.ColorIndex = 5
　End With
　With Selection.Borders(xlEdgeBottom)
　　.LineStyle = xlContinuous
　　.Weight = xlThick
　　.ColorIndex = 5
　End With
　With Selection.Borders(xlEdgeRight)
　　.LineStyle = xlContinuous
　　.Weight = xlThick
　　.ColorIndex = 5
　End With
　With Selection.Borders(xlInsideVertical)
　　.LineStyle = xlContinuous
　　.Weight = xlThin
　　.ColorIndex = xlAutomatic
　End With
　With Selection.Borders(xlInsideHorizontal)
　　.LineStyle = xlContinuous
　　.Weight = xlThin
　　.ColorIndex = xlAutomatic
　End With
　For i = 3 To 34
　　L = Cells(i, 7).Left
　　LL = Cells(i, 9).Left
　　T = Cells(i, 7).Top
　　H = Cells(i, 7).Height
　　W = Cells(i, 7).Width
　　Cells(i, 6).Value = i - 2
　　Cells(i, 8).Value = i - 2 + 32
　　ActiveSheet.Shapes.AddShape(msoShapeRectangle, L, T, W, H).Select
　　Selection.ShapeRange.Fill.ForeColor.SchemeColor = i - 2
　　ActiveSheet.Shapes.AddShape(msoShapeRectangle, LL, T, W, H).Select
　　Selection.ShapeRange.Fill.ForeColor.SchemeColor = i - 2 + 32
　　Cells(i, 3).Value = i + 25
　　Cells(i, 4).Interior.ColorIndex = i + 25
　　If i > 7 Then
　　　Cells(i, 1).Value = i - 7
　　　Cells(i, 2).Interior.ColorIndex = i - 7
　　End If
　Next
End Sub
　　　このコードの使い方は、マクロの使い方(１)標準モジュールにあります。

上のコードでデフォルト値を変えてみました。
文字サイズ11ポイント、ＭＳ Ｐゴシック、セルの書式は標準のまま、右寄せ。
半角数字を1文字づつスペースを空けて入力した場合です。
Sub miko_test()
　Dim aa As Double, a(2) As Double, b As Integer, c As Integer, i As Integer, j As Integer
　b = 5 　　　　　 '区切り線の数の、デフォルト値
　a(1) = 10　　　 '一番右端の区切り線間隔の、デフォルト値
　a(2) = 9 　　　　'その他の区切り線間隔の、デフォルト値
　b = Application.InputBox(Prompt:="ひとつのセル内に、何本の区切り線を引きますか？", Default:=b, Type:=1)
　a(1) = Application.InputBox(Prompt:="一番右端の区切り線の間隔は何ポイントにしますか？", Default:=a(1), Type:=1)
　a(2) = Application.InputBox(Prompt:="その他の区切り線の間隔は何ポイントにしますか？", Default:=a(2), Type:=1)
　If b = False Or b < 1 Then Exit Sub
　If a(1) = False Or a(1) < 0 Then Exit Sub
　If a(2) = False Or a(2) < 0 Then Exit Sub
　aa = Selection.Left + Selection.Width
　For i = Selection.Columns(Selection.Columns.Count).Column To Selection.Columns(1).Column Step -1
　　aa = Cells(, i).Left + Cells(, i).Width - a(1)
　　ActiveSheet.Shapes.AddLine(aa, Selection.Top, aa, Selection.Top + Selection.Height).Select
　　Selection.ShapeRange.Line.DashStyle = msoLineRoundDot 　　　'点線丸
　　For j = 2 To b
　　　aa = aa - a(2)
　　　ActiveSheet.Shapes.AddLine(aa, Selection.Top, aa, Selection.Top + Selection.Height).Select
　　　Selection.ShapeRange.Line.DashStyle = msoLineRoundDot 　　'点線丸
　　Next
　Next
End Sub
　　このコードの使い方は、マクロの使い方(１)標準モジュールにあります。